hughesPJ

Headline

Unparsing in Language:Haskell with a pretty printing combinator library

This contribution demonstrates unparsing, i.e., rendering a term-based representation as according to a some specific text-based concrete syntax. The unparser is described at a relatively high level of abstraction by means of an appropriate library in Language:Haskell.

Illustration

Input of unparsing is a term-based representation like this; "..." indicates an elision:

sampleCompany = Company
  "Acme Corporation"
  [ Department "Research"
      (Employee "Craig" "Redmond" 123456)
      []
      [ Employee "Erik" "Utrecht" 12345,
        Employee "Ralf" "Koblenz" 1234
      ],
    Department "Development"
      ...
  ]

Output of unparsing is a test-based representation like this:

company "Acme Corporation" {
  department "Research" {
    manager "Craig" {
      address "Redmond"
      salary 123456.0
    }
    employee "Erik" {
      address "Utrecht"
      salary 12345.0
    }
    employee "Ralf" {
      address "Koblenz"
      salary 1234.0
    }
  }
  department "Development" {
    ...
  }
}

Here is the function for unparsing:

unparse :: Company -> Doc
unparse (Company n ds) =
  bracy "company" n (vcat (map unparseD ds))
  where
    bracy :: String -> String -> Doc -> Doc
    bracy k n d =
         text k <+> doubleQuotes (text n) <+> text "{"
      $$ nest 2 d
      $$ text "}"
    unparseD :: Department -> Doc
    unparseD (Department n m ds es) =
      bracy "department" n (vcat (   [unparseE "manager" m]
                                ++ map unparseD ds
                                ++ map (unparseE "employee") es))
      where
        unparseE :: String -> Employee -> Doc
        unparseE k (Employee n a s) = bracy k n (a' $$ s')
          where
            a' = text "address" <+> doubleQuotes (text a)
            s' = text "salary" <+> text (show s)

It uses various combinators of Technology:HughesPJ all over the place. For instance, it uses vcat to vertically compose departments; it uses nest to achieve indentation for constituents of companies, departments, and employees. Overall, all the subexpressions render the company terms to a library-specific type of Doc, which is essentially an abstraction over text.

Relationships

The data model is the same as the one of Contribution:haskellComposition.
The textual output format is the same as the one parsed by Contribution:haskellParsec.